1	# =====================================================================
     2	# bloggerRecentPosts.awk: Blogger API 1.0
     3	#
     4	# Copyright (c) 2007,2009,2010 Carlo Strozzi
     5	#
     6	# This program is free software; you can redistribute it and/or modify
     7	# it under the terms of the GNU General Public License as published by
     8	# the Free Software Foundation; version 2 dated June, 1991.
     9	#
    10	# This program is distributed in the hope that it will be useful,
    11	# but WITHOUT ANY WARRANTY; without even the implied warranty of
    12	# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
    13	# GNU General Public License for more details.
    14	#
    15	# You should have received a copy of the GNU General Public License
    16	# along with this program; if not, write to the Free Software
    17	# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
    18	#
    19	# =====================================================================
    20	
    21	BEGIN {
    22	
    23	  i=j=0; delete a; delete b; delete c
    24	
    25	  url = ENVIRON["CSA_RPC_URI"] "/" ENVIRON["CSA_LANG"] "/"
    26	
    27	  page_dir = _rcget("tw_gstem")
    28	
    29	  # I use the unixified group name as a URI here, so that
    30	  # blogger.getRecentPosts does not need to read the actual group
    31	  # record into memory. Fortunately the TW design provides enough
    32	  # flexibility :-)
    33	
    34	  g_name = _rcget("cgi.group")
    35	
    36	  printf("<array>\n<data>")
    37	}
    38	
    39	/^\001/ { next }			# skip table header, if any.
    40	
    41	{
    42	  # Load each page in turn, showing links to nonexistent wiki pages
    43	  # within the same group.
    44	
    45	  # k_page,p_ctime,p_name,p_creau,p_uri,\
    46	  #	p_descr,p_vtime,p_modau,p_tags,p_allow,k_node,p_link,p_store
    47	
    48	  split($0,a,"\t")			# split each record into fields.
    49	
    50	  split(a[3],c,".")			# page category, if any.
    51	
    52	  if (a[4] == _NULL) a[4] = _nlsmap(_NULL,"anonymous")
    53	
    54	  # Fix 'ctime' to meet XML-RPC specs.
    55	  gsub(/-/,"",a[2]); sub(/ /,"T",a[2])
    56	
    57	  page = page_dir "/" a[1] "+wki"
    58	
    59	  # Load each page body in turn.
    60	
    61	  value = _NULL
    62	  while (getline tmp1 < page > 0) value = value tmp1; close(page)
    63	
    64	  # Skip empty pages, as they are to be considered as logically deleted.
    65	  # This test should now be obsolete, but I'll leave it in place still
    66	  # for a while, as it does not cost much anyway since this program
    67	  # needs lo load the page bodies also for other reasons, see below.
    68	
    69	  if (value !~ /(>[^<>]+|[^<>]+<)/) next
    70	
    71	  # CSA tag markers must be escaped, or _envtoxml() will happily
    72	  # interpret anything typed by the user into the file !!
    73	
    74	  gsub(/\$\[/,"\\&#36;[",value)
    75	
    76	  # If this group style is "wiki" then retain only the page abstract,
    77	  # if present. Otherwise, if either no abstract can be isolated or
    78	  # the group has been given a "blog" style, then the actual page body
    79	  # will be used. See also the call to _wikicpi() further down.
    80	
    81	  # Retain only page abstracts, if defined.
    82	
    83	  if (_rcget("TNS_TW_STYLE",1) != "blog") {
    84	     sub(/.*\(::ab:\)/,"",value)
    85	     sub(/\(:ab::\).*/,"",value)
    86	
    87	     sub(/\(:i:\).*/,_NULL,value)
    88	  }
    89	
    90	  #tmp = "<a[ \\t\\r\\n]+href[ \\t\\r\\n]*=[ \\t\\r\\n]*['\"]"
    91	  #tmp = "<a[^a-z]+[^>]*[^a-z]href[^a-z=]*=[^'\"]*['\"]"
    92	
    93	  i = split(value,b,/<a[^a-z]+/)
    94	
    95	  value = b[1]
    96	
    97	  for (j=2; j<=i; j++) {
    98	
    99	      # The "\001" trick below is not to be fooled by an "href="
   100	      # other than the one at the beginning of the matched string.
   101	
   102	      sub(/href/,"\001",b[j])
   103	
   104	      # I'm only concerned with href anchors here.
   105	
   106	      #if (b[j] !~ /[^a-z]*\001[^a-z=]*=[^a-z]+(http|\/)/) {
   107	      if (b[j] !~ /[^\001]*\001[^=]*=[^a-z]+/) {
   108		 sub(/\001/," href",b[j])
   109	         value = value "<a " b[j]
   110		 continue
   111	      }
   112	
   113	      tmp2 = b[j]
   114	      sub(/[^\001]*\001[^=]*=[^'"]*['"]/,_NULL,b[j])
   115	      sub(/\001.*/,_NULL,tmp2)
   116	
   117	      sub(/\001/," href",b[j])		# revert the \001 trick.
   118	      sub(/['"]/,"'",b[j])		# trailing quote.
   119	
   120	      # Turn host-less absolute URLs into canonical form.
   121	      if (b[j] ~ /^\//) {
   122		 tmp = ENVIRON["CSA_RPC_URI"]
   123		 sub(/:.*/,"://",tmp)
   124		 if (ENVIRON["SERVER_PORT"] == "80")
   125		    b[j] = tmp ENVIRON["CSA_FQDN"] b[j]
   126		 else b[j] = tmp ENVIRON["CSA_FQDN"] \
   127			":" ENVIRON["SERVER_PORT"] b[j]
   128	      }
   129	
   130	      tmp = "^" _escreg(url)
   131	
   132	      if (b[j] ~ tmp) {
   133	
   134	         tmp = b[j]
   135	         sub(/'.*/,"",tmp)               # retain only page name.
   136	         sub(/.*\//,"",tmp)
   137	         tmp = unixify(_uridecode(tmp,_O_PATHINFO),1)
   138	
   139	         # If the specified page does not exist (and we are
   140	         # at the confirmation prompt) mark it with a (?).
   141	
   142	         if (_stat(ENVIRON["CSA_ROOT"] "/var/pages/" \
   143	            ENVIRON["CSA_LANG"] "/" _rcget("cgi.group") "/" \
   144	            tmp "+wki") != _TRUE)
   145	            sub(/<\/a>/,"<sup>?</sup></a>",b[j])
   146	      }
   147	
   148	
   149	      # This is to make sure hyperlinks do not contain blanks,
   150	      # or the W3C validator may complain.
   151	
   152	      tmp1 = b[j]
   153	      sub(/['"].*/,_NULL,tmp1)
   154	      sub(/[^'"]+/,_NULL,b[j])
   155	      gsub(/ /,"+",tmp1)
   156	      b[j] = tmp1 b[j]
   157	
   158	      # Now spot external links and label them as such.
   159	
   160	      b[j] = "href=" b[j]
   161	      sub(/=/,"='",b[j])		# leading quote.
   162	      b[j] = extLink("<a " tmp2 b[j])
   163	
   164	      value = value b[j]
   165	  }
   166	
   167	  print	"\n<value><struct>\n" \
   168		"<member>\n" \
   169		"<name>content</name>"
   170	
   171	  printf("<value><string>%s",_xmlencode("<title>" a[3]))
   172	
   173	  # Honour the Title-API flag.
   174	  if (_rcget("TNS_API_PROP",2) == "t")
   175	     printf("%s",_xmlencode("|" a[6] "|" a[7] "|" a[8] \
   176				"|" a[9] "|" a[10] "|" a[12] "|" a[13]))
   177	
   178	  printf(_xmlencode("</title>"))
   179	
   180	  if (c[2] != _NULL)
   181		printf("%s",_xmlencode("<category>" c[1] "</category>"))
   182	
   183	  # If the invoking user is an editor we have no other choice but assume
   184	  # that she wants to edit entries, including any embedded user-level
   185	  # CPI's, otherwise the latter will be parsed for display. If an editor
   186	  # wants to rather pull the rendered page over RPC then she will have
   187	  # to log-out and log-in again with an unprivileged account. Given the
   188	  # limited capabilities of the Blogger API compared with the full-blown
   189	  # TW Web API, it looks like this is the only sensible behaviour.
   190	  # Note: most (all ?) API methods only make sense if the user is an
   191	  # editor, so they are currently unavailable to others and therefore
   192	  # tests like the following never match.
   193	
   194	  # Perform Wiki parsing at this stage.
   195	  if ("," ENVIRON["TNS_AUTH_GRP"] "," !~ /,editor,/)
   196						value = _wikicpi(value)
   197	
   198	  if (_rcget("cgi.numeric",1) == _NULL)
   199	     id = "<string>" ENVIRON["CSA_LANG"] "/" g_name "/" a[1] "</string>"
   200	  else id = "<int>" a[11] "</int>"
   201	
   202	  print _xmlencode(value) "</string></value>\n" \
   203		"</member>\n" \
   204		"<member>\n" \
   205		"<name>userId</name>\n" \
   206		"<value><string>" a[4] "</string></value>\n" \
   207		"</member>\n" \
   208		"<member>\n" \
   209		"<name>postId</name>\n" \
   210		"<value>" id "</value>\n" \
   211		"</member>\n" \
   212		"<member>\n" \
   213		"<name>dateCreated</name>\n" \
   214		"<value><dateTime.iso8601>" a[2] "</dateTime.iso8601></value>\n" \
   215		"</member>"
   216	
   217	  printf("</struct></value>")
   218	
   219	} 
   220	
   221	END {
   222	
   223	  print "\n</data>\n</array>"
   224	}
   225	
   226	# EOF