1	# =====================================================================
     2	# groupRecentPages.awk: W-TW group recent-pages applet.
     3	#
     4	# Copyright (c) 2007,2008,2009,2010,2011 Carlo Strozzi
     5	#
     6	# This program is free software; you can redistribute it and/or modify
     7	# it under the terms of the GNU General Public License as published by
     8	# the Free Software Foundation; version 2 dated June, 1991.
     9	#
    10	# This program is distributed in the hope that it will be useful,
    11	# but WITHOUT ANY WARRANTY; without even the implied warranty of
    12	# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
    13	# GNU General Public License for more details.
    14	#
    15	# You should have received a copy of the GNU General Public License
    16	# along with this program; if not, write to the Free Software
    17	# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
    18	#
    19	# =====================================================================
    20	
    21	BEGIN {
    22	
    23	  fmt1=fmt2=""; i=j=k=0; delete a; delete b; delete c
    24	  delete d; delete e; delete f1; delete f2
    25	
    26	  # work-out the format of each page header.
    27	  fmt1 = readfmt("tw-page-header")
    28	  gsub(/%/,"%%",fmt1)			# turn plain '%' into '%%'.
    29	  gsub(/\\/,"\\\\&",fmt1)		# turn '\' into '\\'.
    30	  gsub(/[\n\r]+/,"",fmt1)		# just in case.
    31	  tmp = fmt1
    32	
    33	  # Handle custom positioning of output tokens.
    34	  sub(/.*\[:/,_NULL,tmp); sub(/:].*/,_NULL,tmp)
    35	  tmp = _strip(tmp,_O_MIDDLE)
    36	  if (tmp !~ /^[0-5 ]+$/) tmp = "1 2 3 4 5"
    37	
    38	  # pad missing arg specs with "0".
    39	  if ((i=split(tmp,f1," ")) < 5) {
    40	     while (i++ <= 5) tmp = tmp " 0"
    41	     i = split(tmp,f1," ")
    42	  }
    43	
    44	  tmp = _NULL
    45	
    46	  for (j=1; j<=i; j++) {
    47	      if (j > 5) break		# ignore excess arg specs.
    48	      if (!sub(/<tw:s[ \t]*\/>/,"%s",fmt1)) fmt1 = fmt1 "<!-- %s -->"
    49	      tmp = tmp " " f1[j]
    50	  }
    51	
    52	  # encode any extra markers.
    53	  gsub(/<tw:s[ \t]*\/>/,"\\&lt;tw:s/\\&gt;",fmt1)
    54	
    55	  fmt1 = fmt1 "\n"
    56	
    57	  split(_strip(tmp),f1," "); f1[0] = 0
    58	
    59	  # work-out the format of each page footer.
    60	  fmt2 = readfmt("tw-page-footer")
    61	  gsub(/%/,"%%",fmt2)			# turn plain '%' into '%%'.
    62	  gsub(/\\/,"\\\\&",fmt2)		# turn '\' into '\\'.
    63	  gsub(/[\n\r]+/,"",fmt2)		# just in case.
    64	  tmp = fmt2
    65	
    66	  # Handle custom positioning of output tokens.
    67	  sub(/.*\[:/,_NULL,tmp); sub(/:].*/,_NULL,tmp)
    68	  tmp = _strip(tmp,_O_MIDDLE)
    69	  if (tmp !~ /^[0-2 ]+$/) tmp = "1 2"
    70	
    71	  # pad missing arg specs with "0".
    72	  if ((i=split(tmp,f2," ")) < 2) {
    73	     while (i++ <= 2) tmp = tmp " 0"
    74	     i = split(tmp,f2," ")
    75	  }
    76	
    77	  tmp = _NULL
    78	
    79	  for (j=1; j<=i; j++) {
    80	      if (j > 2) break		# ignore excess arg specs.
    81	      if (!sub(/<tw:s[ \t]*\/>/,"%s",fmt2)) fmt2 = fmt2 "<!-- %s -->"
    82	      tmp = tmp " " f2[j]
    83	  }
    84	
    85	  # encode any extra markers.
    86	  gsub(/<tw:s[ \t]*\/>/,"\\&lt;tw:s/\\&gt;",fmt2)
    87	
    88	  fmt2 = fmt2 "\n"
    89	
    90	  split(_strip(tmp),f2," "); f2[0] = 0
    91	
    92	  page_dir = _rcget("tw_gstem")
    93	  g_uri = _rcget("tbl_group.g_uri")
    94	
    95	  url = ENVIRON["CSA_RPC_URI"] "/" ENVIRON["CSA_LANG"] "/"
    96	
    97	  e[0] = _NULL
    98	}
    99	
   100	/^\001/ { next }			# skip table header, if any.
   101	
   102	{
   103	  # Load each page in turn, setting the proper headers/footers and
   104	  # showing links to nonexistent wiki pages within the same group.
   105	  # Note that while I use 'ctime' for the 'recent-links' view, I
   106	  # prefer to use 'vtime' here as I think it makes more sense for
   107	  # both this view and the 'recent-headlines' one.
   108	
   109	  # k_page, p_vtime, p_name, p_modau, p_uri, p_descr, p_etime
   110	
   111	  split($0,a,"\t")			# split each record into fields.
   112	
   113	  # Exclude hidden pages from this view. Note that this is now done
   114	  # directly by 'updatePage' before the input list is fed into this
   115	  # script, so that we always get the configured no. of entries on
   116	  # output even after skipping hidden/restricted/redirected pages.
   117	  #
   118	  #if (a[6] ~ /^ *-/) next
   119	
   120	  if (a[4] != _NULL) ftr = a[4]
   121	  else ftr = _nlsmap(_NULL,"anonymous")
   122	
   123	  # Remove any redirection URL from visible description.
   124	  sub(/ *\+*\(:redirect .*/,_NULL,a[6])
   125	
   126	  if (a[6] == _NULL) a[6] = a[3]		# default description
   127	
   128	  # Make sure we pick the new content of a page which is being edited.
   129	  if (a[1] == _rcget("cgi.page")) page = ENVIRON["TNS_NEW_CONTENT"]
   130	  else page = page_dir "/" a[1] "+wki"
   131	
   132	  # strip ranking.
   133	  sub(/^.*,/,"",a[2])
   134	
   135	  # page header.
   136	
   137	  tmp = a[2]
   138	  gsub(/ /,"T",tmp)
   139	  gsub(/:/,"_",tmp)
   140	  tmp = tmp "." ENVIRON["CSA_RID"]
   141	  tmp = _xmlencode(tmp "." NR)
   142	
   143	  split(_localdate(a[2],1),b," "); sub(/:..$/,"",b[2])
   144	
   145	  split(_localdate(a[7],1),c," "); sub(/:..$/,"",c[2])
   146	
   147	  # Load each page body in turn.
   148	  value = _NULL
   149	  while (getline tmp1 < page > 0) value = value tmp1; close(page)
   150	
   151	  # Skip empty pages, as they are to be considered as logically deleted.
   152	  # This test should now be obsolete, but I'll leave it in place still
   153	  # for a while, as it does not cost much anyway since this program
   154	  # needs lo load the page bodies also for other reasons, see below.
   155	
   156	  if (value !~ /[a-zA-Z0-9]/) next		# skip empty pages.
   157	
   158	  # Insert entry separator, it may turn out to be of use in the future.
   159	  if (NR > 1) value = "<!-- (:entry:) -->" value
   160	
   161	  e[1] = tmp
   162	  e[2] = b[1]
   163	  e[3] = b[2]
   164	  e[4] = c[1]
   165	  e[5] = c[2]
   166	
   167	  # print header.
   168	  printf(fmt1,e[f1[1]],e[f1[2]],e[f1[3]],e[f1[4]],e[f1[5]])
   169	
   170	  # CSA tag markers must be escaped, or _envtoxml() will happily
   171	  # interpret anything typed by the user into the file !!
   172	
   173	  gsub(/\$\[/,"\\&#36;[",value)
   174	
   175	  # Retain only the page abstract if defined.
   176	  # See also the call to _wikicpi() further down.
   177	
   178	  # Retain only page abstracts for this view, where defined.
   179	  sub(/.*\(::ab:\)/,"<!-- (:entry:) --><span class='tw-abstract'>",value)
   180	  sub(/\(:ab::\).*/,"</span>",value)
   181	
   182	  #if (sub(/\(:i:\).*/," ... <span class='tw-continue'>" \
   183	  #	"(<a href='" _xmlencode(url g_uri "/" a[5]) "'>" \
   184	  #	_xmlencode(_nlsmap(_NULL,"continue")) "</a>)</span>",value))
   185	  #					value = "<!-- (:entry:) -->" value
   186	
   187	  sub(/\(:i:\).*/," ... <span class='tw-continue'>" \
   188		"(<a href='" _xmlencode(url g_uri "/" a[5]) "'>" \
   189		_xmlencode(_nlsmap(_NULL,"continue")) "</a>)</span>",value)
   190	
   191	  # Try and fix any orphan opening/closing tags produced by the
   192	  # above truncation process. This is done only if we are in XHTML
   193	  # mode, because it is tricky and it may not work in every possible
   194	  # situation. I also rely on the fact that a CPI will not be placed in
   195	  # the middle of things like <option> or <li>, as that would really be
   196	  # fishing for troubles on the part of the user. In other than XHTML
   197	  # mode I prefer not to try and fix orphans, and let everything to the
   198	  # user's responsibility. After all, in other than XHTML things are
   199	  # much less likely to break because of well-formedness problems.
   200	
   201	  if (_bool(ENVIRON["CSA_XMLISH"]) == _TRUE) {
   202	
   203	     delete c; delete is_open; x=0; pre=_NULL
   204	
   205	     # Fix most typical orphans first, as sequences like <br></br>
   206	     # are not tolerated in other than XHTML .
   207	
   208	     gsub(/<br>/,"<br />",value)
   209	     gsub(/<hr>/,"<hr />",value)
   210	
   211	     tmp1 = value
   212	
   213	     gsub(/<[^>]+\/>/,"",tmp1)		# strip empty elements.
   214	     gsub(/<[!?][^>]+>/,"",tmp1)		# strip comments and PI's.
   215	
   216	     i = split(tmp1,c,"<")
   217	
   218	     for (j=2; j<=i; j++) {
   219		 sub(/>.*/,"",c[j])
   220		 sub(/[^>]+>/,"",c[j])
   221		 if (c[j] !~ /^\//) is_open[++x] = c[j]
   222		 else x ? x-- : pre = "<" substr(c[j],2) ">"
   223	     }
   224	
   225	     value = pre value
   226	
   227	     while (x--) value = value "</" is_open[x+1] ">"
   228	  }
   229	
   230	  # end of the orphan-fixing code.
   231	
   232	  #tmp = "<a[ \\t\\r\\n]+href[ \\t\\r\\n]*=[ \\t\\r\\n]*['\"]"
   233	  #tmp = "<a[^a-z]+[^>]*[^a-z]href[^a-z=]*=[^'\"]*['\"]"
   234	
   235	  i = split(value,b,/<a[^a-z]+/)
   236	
   237	  value = b[1]
   238	
   239	  for (j=2; j<=i; j++) {
   240	
   241	      # The "\001" trick below is not to be fooled by an "href="
   242	      # other than the one at the beginning of the matched string.
   243	
   244	      sub(/href/,"\001",b[j])
   245	
   246	      # I'm only concerned with href anchors here.
   247	
   248	      #if (b[j] !~ /[^a-z]*\001[^a-z=]*=[^a-z]+(http|\/)/) {
   249	      if (b[j] !~ /[^\001]*\001[^=]*=[^a-z]+/) {
   250		 sub(/\001/," href",b[j])
   251	         value = value "<a " b[j]
   252		 continue
   253	      }
   254	
   255	      tmp2 = b[j]
   256	      sub(/[^\001]*\001[^=]*=[^'"]*['"]/,_NULL,b[j])
   257	      sub(/\001.*/,_NULL,tmp2)
   258	
   259	      sub(/\001/," href",b[j])		# revert the \001 trick.
   260	      sub(/['"]/,"'",b[j])		# trailing quote.
   261	
   262	      # Turn host-less absolute URLs into canonical form.
   263	      if (b[j] ~ /^\//) {
   264		 tmp = ENVIRON["CSA_RPC_URI"]
   265		 sub(/:.*/,"://",tmp)
   266		 if (ENVIRON["SERVER_PORT"] == "80")
   267		    b[j] = tmp ENVIRON["CSA_FQDN"] b[j]
   268		 else b[j] = tmp ENVIRON["CSA_FQDN"] \
   269			":" ENVIRON["SERVER_PORT"] b[j]
   270	      }
   271	
   272	      tmp = "^" _escreg(url)     
   273	
   274	      if (b[j] ~ tmp) {
   275	
   276	         tmp = b[j]
   277	         sub(/'.*/,"",tmp)               # retain only page name.
   278		 k = split(tmp,d,"/")		 # save group name for later
   279	         sub(/.*\//,"",tmp)
   280	         tmp = unixify(_uridecode(tmp,_O_PATHINFO),1)
   281	
   282	         # If the specified page does not exist (and we are at the
   283		 # confirmation prompt) mark it with a (?). These checks are
   284		 # likely not to be bullet-proof yet, with pages belonging into
   285		 # an equally-named group but a different TW instance on the
   286		 # same host being marked as non-existent in the current TW,
   287		 # but we'll see.
   288	
   289		 #if (tmp "+wki" != _rcget("cgi.page") && \
   290		 if (tmp !~ /^([1-9]|tw-)/ && \
   291		    tmp != _rcget("cgi.page") && \
   292		    d[k-1] == _rcget("cgi.group") && \
   293	            _stat(ENVIRON["CSA_ROOT"] "/var/pages/" \
   294	            ENVIRON["CSA_LANG"] "/" _rcget("cgi.group") "/" \
   295	            tmp "+wki") != _TRUE)
   296	            sub(/<\/a>/,"<sup>?</sup></a>",b[j])
   297	      }
   298	
   299	
   300	      # This is to make sure hyperlinks do not contain blanks,
   301	      # or the W3C validator may complain.
   302	
   303	      tmp1 = b[j]
   304	      sub(/['"].*/,_NULL,tmp1)
   305	      sub(/[^'"]+/,_NULL,b[j])
   306	      gsub(/ /,"+",tmp1)
   307	      b[j] = tmp1 b[j]
   308	
   309	
   310	      # Now spot external links and label them as such.
   311	
   312	      b[j] = "href=" b[j]
   313	      sub(/=/,"='",b[j])		# leading quote.
   314	      b[j] = extLink("<a " tmp2 b[j])
   315	
   316	      value = value b[j]
   317	  }
   318	
   319	  # Perform Wiki parsing last.
   320	
   321	  # Strip selected CPI's from views, add more CPI's as needed.
   322	  gsub(/\(:chart[^:]+:\)/,"",value)
   323	
   324	  # Save on overhead if there's no RDFa to parse.
   325	  if (value ~ /\(:v-/) {
   326	     if (_rcget("TNS_GROUP_MISC_PROP",4) == "rdfa")
   327	  		printf("%s\n",_rdfacpi(_wikicpi(value)))
   328	     else printf("%s\n",_mfmtcpi(_wikicpi(value)))
   329	  }
   330	  else printf("%s\n",_wikicpi(value))
   331	
   332	  # page footer.
   333	
   334	  e[1] = _xmlencode(ftr)
   335	  e[2] = url g_uri "/" a[5]
   336	  printf(fmt2,e[f2[1]],e[f2[2]])		# print footer.
   337	} 
   338	
   339	# EOF