1	# =====================================================================
     2	# pageTrackBacks.awk: W-TW page trackback applet.
     3	#
     4	# Copyright (c) 2007,2009 Carlo Strozzi
     5	#
     6	# This program is free software; you can redistribute it and/or modify
     7	# it under the terms of the GNU General Public License as published by
     8	# the Free Software Foundation; version 2 dated June, 1991.
     9	#
    10	# This program is distributed in the hope that it will be useful,
    11	# but WITHOUT ANY WARRANTY; without even the implied warranty of
    12	# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
    13	# GNU General Public License for more details.
    14	#
    15	# You should have received a copy of the GNU General Public License
    16	# along with this program; if not, write to the Free Software
    17	# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
    18	#
    19	# =====================================================================
    20	
    21	BEGIN {
    22	
    23	  delete a; delete b		# just in case.
    24	
    25	  # build links to recent pages.
    26	
    27	  # Set output format string.
    28	
    29	  fmt = readfmt("tw-page-trackbacks")
    30	  gsub(/%/,"%%",fmt)		# turn plain '%' into '%%'.
    31	  gsub(/\\/,"\\\\&",fmt)	# turn '\' into '\\'.
    32	  gsub(/[\n\r]+/,"",fmt)	# just in case.
    33	
    34	  # this format string is currently not customizable.
    35	  for (i=1; i<=3; i++) {
    36	      if (!sub(/<tw:s[ \t]*\/>/,"%s",fmt)) fmt = fmt "<!-- %s -->"
    37	  }
    38	
    39	  # encode any extra markers.
    40	  gsub(/<tw:s[ \t]*\/>/,"\\&lt;tw:s/\\&gt;",fmt)
    41	 
    42	  fmt = fmt "\n"
    43	}
    44	
    45	/^\001/ { next }			# skip table header, if any.
    46	
    47	{
    48	    # k_tbkurl, t_ctime, t_title, t_creip
    49	
    50	    split($0,a,"\t")
    51	
    52	    gsub(/ /,"%20",a[1])			# just in case.
    53	
    54	    out = sprintf(fmt,_localdate(a[2]),_xmlencode(a[1]),_xmlencode(a[3]))
    55	
    56	    i = split(out,b,/<a[^a-z]+/)
    57	
    58	    out = b[1]
    59	
    60	    for (j=2; j<=i; j++) {
    61	
    62	        # The "\001" trick below is not to be fooled by an "href="
    63	        # other than the one at the beginning of the matched string.
    64	
    65	        sub(/href/,"\001",b[j])
    66	
    67	        # I'm only concerned with href anchors here.
    68	
    69	        if (b[j] !~ /[^\001]*\001[^=]*=[^a-z]+/) {
    70		   sub(/\001/," href",b[j])
    71	           out = out "<a " b[j]
    72		   continue
    73	        }
    74	
    75	        tmp = b[j]
    76	        sub(/[^\001]*\001[^=]*=[^'"]*['"]/,_NULL,b[j])
    77	        sub(/\001.*/,_NULL,tmp)
    78	
    79	        sub(/\001/," href",b[j])		# revert the \001 trick.
    80	        sub(/['"]/,"'",b[j])		# trailing quote.
    81	
    82	        # Turn host-less absolute URLs into canonical form.
    83	        if (b[j] ~ /^\//) {
    84		   tmp = ENVIRON["CSA_RPC_URI"]
    85		   sub(/:.*/,"://",tmp)
    86		   if (ENVIRON["SERVER_PORT"] == "80")
    87		      b[j] = tmp ENVIRON["CSA_FQDN"] b[j]
    88		   else b[j] = tmp ENVIRON["CSA_FQDN"] \
    89			  ":" ENVIRON["SERVER_PORT"] b[j]
    90	        }
    91	
    92	
    93		# This is to make sure hyperlinks do not contain blanks,
    94		# or the W3C validator may complain.
    95	
    96		tmp1 = b[j]
    97		sub(/['"].*/,_NULL,tmp1)
    98		sub(/[^'"]+/,_NULL,b[j])
    99		gsub(/ /,"+",tmp1)
   100		b[j] = tmp1 b[j]
   101	
   102		# Now spot external links and label them as such.
   103	
   104	        b[j] = "href=" b[j]
   105	        sub(/=/,"='",b[j])		# leading quote.
   106	        b[j] = extLink("<a " tmp b[j])
   107	
   108	        out = out b[j]
   109	  }
   110	
   111	  # Unikley what happens with showPage.awk, where the additional
   112	  # rel="" stuff is added to outbound links on-the-fly, here that
   113	  # same stuff gets statically cast into the output XML file, and
   114	  # it is only revisited whenever a new trackback is added.
   115	
   116	  printf("%s",out)
   117	} 
   118	
   119	# EOF